Data.Codec.JSON

type Codec a = Codec' (Except DecodeError) JSON a

Codec type for Json values.

encode :: forall a b c d. Codec (Except DecodeError) a b c d -> c -> b

Encodes a value as JSON using the specified code.

decode :: forall a b c d. Codec (Except DecodeError) a b c d -> a -> Either DecodeError d

Tries to decode JSON to a value using the specified code.

json :: Codec JSON

The "identity codec" for Json values.

null :: Codec Unit

A codec for null values in Json.

boolean :: Codec Boolean

A codec for Boolean values in Json.

number :: Codec Number

A codec for Number values in Json.

int :: Codec Int

A codec for Int values in Json.

string :: Codec String

A codec for String values in Json.

codePoint :: Codec CodePoint

A codec for Codepoint values in Json.

char :: Codec Char

A codec for Char values in Json.

jarray :: Codec JArray

A codec for JArray values in Json. This does not decode the values of the array, for that use array for a general array decoder, or indexedArray with index to decode fixed length array encodings.

jobject :: Codec JObject

A codec for JObject values in Json.

void :: Codec Void

A codec for Void values.

array :: forall a. Codec a -> Codec (Array a)

A codec for arbitrary length Arrays where every item in the array shares the same type.

import Data.Codec.JSON as CJ

codecIntArray ∷ CJ.Codec (Array Int)
codecIntArray = CJ.array CJ.int

type IndexedCodec a = Codec (Except DecodeError) JArray (List JSON) a a

Codec type for specifically indexed JArray elements.

indexedArray :: forall a. IndexedCodec a -> Codec a

A codec for types that are encoded as an array with a specific layout.

For example, if we'd like to encode a Person as a 2-element array, like ["Rashida", 37], we could write the following codec:

import Data.Codec.JSON ((~))
import Data.Codec.JSON as CJ

type Person = { name ∷ String, age ∷ Int }

codecPerson ∷ CJ.Codec Person
codecPerson = CJ.indexedArray $
  { name: _, age: _ }
    <$> _.name ~ CJ.index 0 CJ.string
    <*> _.age ~ CJ.index 1 CJ.int

index :: forall a. Int -> Codec a -> IndexedCodec a

A codec for an item in an indexedArray.

type PropCodec a = Codec (Except DecodeError) JObject (List (Tuple String JSON)) a a

Codec type for JObject prop/value pairs.

object :: forall a. PropCodec a -> Codec a

A codec for objects that are encoded with specific properties.

See also Data.Codec.JSON.Record.object for a more commonly useful version of this function.

prop :: forall a. String -> Codec a -> PropCodec a

A codec for a property of an object.

record :: PropCodec (Record ())

The starting value for a object-record codec. Used with recordProp it provides a convenient method for defining codecs for record types that encode into JSON objects of the same shape.

For example, to encode a record as the JSON object { "name": "Karl", "age": 25 } we would define a codec like this:

import Data.Codec.JSON as CJ
import Type.Proxy (Proxy(..))

type Person = { name ∷ String, age ∷ Int }

codecPerson ∷ CJ.Codec Person
codecPerson =
  CJ.object $ CJ.record
    # CJ.recordProp (Proxy :: _ "name") CJ.string
    # CJ.recordProp (Proxy :: _ "age") CJ.int

See also Data.Codec.JSON.Record.object for a more commonly useful version of this function.

recordProp :: forall p a r r'. IsSymbol p => Cons p a r r' => Proxy p -> Codec a -> PropCodec (Record r) -> PropCodec (Record r')

Used with record to define codecs for record types that encode into JSON objects of the same shape. See the comment on record for an example.

recordPropOptional :: forall p a r r'. IsSymbol p => Cons p (Maybe a) r r' => Proxy p -> Codec a -> PropCodec (Record r) -> PropCodec (Record r')

Used with record to define an optional field.

This will only decode the property as Nothing if the field does not exist in the object - having a values such as null assigned will need handling separately.

The property will be omitted when encoding and the value is Nothing.

nullable :: forall a. Codec a -> Codec (Maybe a)

A codec for JSON values that can be null or some other value.

This should not be used if an accurate representation of nested Maybe values is required, as values like Just Nothing cannot be encoded. For nested Maybes consider using Data.Codec.JSON.Common.maybe instead.

named :: forall a. String -> Codec a -> Codec a

A codec for introducing names into error messages - useful when definiting a codec for a type synonym for a record, for instance.

coercible :: forall a b. Coercible a b => String -> Codec a -> Codec b

A codec for types that can be safely coerced.

Accepts the name of the target type as an argument to improve error messaging when the inner codec fails.

prismaticCodec :: forall a b. String -> (a -> Maybe b) -> (b -> a) -> Codec a -> Codec b

Adapts an existing codec with a pair of functions to allow a value to be further refined. If the inner decoder fails an UnexpectedValue error will be raised for JSON input.

This function is named as such as the pair of functions it accepts correspond with the preview and review functions of a Prism-style lens.

An example of this would be a codec for Data.String.NonEmpty.NonEmptyString:

nonEmptyString ∷ CJ.Codec NES.NonEmptyString
nonEmptyString = CJ.prismaticCodec "NonEmptyString" NES.fromString NES.toString CJ.string

Another example might be to handle a mapping from a small sum type to strings:

data Direction = North | South | West | East

directionCodec :: Codec Direction
directionCodec = CJ.prismaticCodec "Direction" dec enc string
  where
    dec = case _ of
      "N" -> Just North
      "S" -> Just South
      "W" -> Just West
      "E" -> Just East
      _ -> Nothing

    enc = case _ of
      North -> "N"
      South -> "S"
      West -> "W"
      East -> "E"

Although for this latter case there are some other options too, in the form of Data.Codec.JSON.Generic.nullarySum and Data.Codec.JSON.Sum.enumSum.

newtype DecodeError

Type for failures while decoding, a path to the point in the JSON that failure occurred, a message describing the problem, and a list of further causes for the failure.

Constructors

• DecodeError DecodeErrorDetails

Instances

• Eq DecodeError
• Ord DecodeError
• Generic DecodeError _
• Newtype DecodeError _
• Show DecodeError
• Semigroup DecodeError

identity :: forall m a. Applicative m => Codec m a a a a

hoist :: forall m m' a b c d. (m ~> m') -> Codec m a b c d -> Codec m' a b c d

fix :: forall m a b. (Codec' m a b -> Codec' m a b) -> Codec' m a b

Operator alias for Data.Profunctor.lcmap (left-associative / precedence 5)

Codec is defined as a Profunctor so that lcmap can be used to target specific fields when defining a codec for a product type. This operator is a convenience for that:

tupleCodec =
  Tuple
    <$> fst ~ fstCodec
    <*> snd ~ sndCodec

Operator alias for Data.Codec.composeFlipped (right-associative / precedence 8)

Operator alias for Data.Codec.compose (right-associative / precedence 8)